lifeboot.asm

   1 bits 16
   2 org 0x7c00
   3
   4 ; =============================================================================
   5
   6 ; settings --------------------------------------------------------------------
   7
   8 %define DEAD ' '            ; char to represent a dead cell
   9 %define ALIVE '#'           ; char to represent an alive cell
  10 %define PRINT_COLOR 0x07    ; grey on black
  11 %define WAIT_DELAY 0x02     ; 0.131072 seconds
  12
  13 ; constants -------------------------------------------------------------------
  14
  15 %define COLS 80
  16 %define ROWS 25
  17 %define VGAPGSZ (COLS * ROWS * 2 + 96)  ; why 96 ??????
  18
  19 ; memory layout ---------------------------------------------------------------
  20
  21 %define ORG 0x7c00
  22 %define VGA 0xb8000
  23 %define DAT ORG + 512
  24
  25 ; static variables ------------------------------------------------------------
  26
  27 %define xss DAT             ; xs() state (word)
  28 %define currvgapg DAT + 2   ; current vga page near pointer (word)
  29
  30 ; =============================================================================
  31
  32 ; entry point -----------------------------------------------------------------
  33
  34 ; initialize segment registers
  35 mov ax, VGA >> 4
  36 mov es, ax
  37
  38 xor ax, ax
  39 mov ds, ax
  40 mov ss, ax
  41
  42 ; set stack pointers
  43 mov bp, ORG
  44 mov sp, bp
  45
  46 ; clear direction flag
  47 cld
  48
  49 ; disable cursor
  50 mov ch, 0x3f                ; cursor start and options
  51 mov ah, 0x01                ; set text-mode cursor shape
  52 int 0x10                    ; video services
  53
  54 ; initialize xss
  55
  56 set_xss_seed:
  57
  58 mov ah, 0x00                ; get
  59 int 0x1a                    ;  system time
  60
  61 cmp dx, 0
  62 je set_xss_seed             ; if seed is 0, xs wont work properly
  63
  64 mov [xss], dx               ; cx:dx = number of clock ticks since midnight
  65
  66 ; initialize currvgapg
  67 mov word [currvgapg], 0
  68
  69 ; start simulation from random state ------------------------------------------
  70
  71 start:
  72
  73 call init_grid
  74
  75 ; apply game of life's rules to determine the next state ----------------------
  76
  77 next_state:
  78
  79 call write_next_vga_page
  80 call wait_keypress
  81 call flip_vga_page
  82
  83 jmp next_state
  84
  85 ; =============================================================================
  86
  87 ; functions -------------------------------------------------------------------
  88
  89 ; delay() - suspend program execution temporarily -----------------------------
  90
  91 ; clobbers ah, cx, dx
  92
  93 delay:
  94
  95 mov cx, WAIT_DELAY          ; cx:dx = interval in microseconds
  96 mov dx, 0
  97
  98 mov ah, 0x86
  99 int 0x15                    ; wait
 100
 101 ret
 102
 103 ; wait_keypress() - wait for any keypress -------------------------------------
 104
 105 ; clobbers: ax
 106
 107 wait_keypress:
 108
 109 mov ah, 0x00        ; read key press
 110 int 0x16            ; keyboard services
 111
 112 ret
 113
 114 ; vsync_wait() - wait for display to enter the next VBlank cycle --------------
 115
 116 ; clobbers ax, dx
 117
 118 vsync_wait:
 119
 120 mov dx, 0x3da               ; input status #1 register
 121
 122 .wait_on:
 123     in al, dx
 124     test al, 0x08           ; vertical retrace bit
 125     jnz .wait_on
 126
 127 .wait_off:
 128     in al, dx
 129     test al, 0x08
 130     jz .wait_off
 131
 132 ret
 133
 134 ; xs() - xorshift pseudorandom number generator -------------------------------
 135
 136 ; output:
 137 ; [xss]     = updated state
 138
 139 ; clobbers bx, dx
 140
 141 xs:
 142
 143 mov bx, [xss]
 144 mov dx, bx
 145
 146 shl dx, 1                   ; dx = xss << 1
 147 xor bx, dx                  ; bx = xss ^ (xss << 1)
 148 mov dx, bx
 149
 150 shr dx, 3                   ; dx = xss' >> 3
 151 xor bx, dx                  ; bx = xss' ^ (xss' >> 3)
 152 mov dx, bx
 153
 154 shl dx, 10                  ; dx = xss'' << 10
 155 xor bx, dx                  ; bx = xss'' ^ (xss'' << 10)
 156 mov [xss], bx
 157
 158 ret
 159
 160 ; init_grid() - initialize grid cells randomly --------------------------------
 161
 162 ; clobbers ax, bx, cx, dx, di
 163
 164 init_grid:
 165
 166 mov ah, PRINT_COLOR         ; ah = color attribute
 167 mov di, [currvgapg]         ; es:di -> grid start
 168 mov cx, COLS * ROWS         ; for each cell
 169
 170 .write_cell:                ; do {
 171     call xs                 ;     [xss] = rand
 172     mov al, DEAD            ;     al = DEAD (likely)
 173
 174     test word [xss], 0b11
 175
 176     jnz  .nz                ;     if ([xss] % 4 == 0)
 177     mov al, ALIVE           ;         al = ALIVE
 178
 179 .nz:
 180     stosw                   ;     [es:di] = ax ; di += 2
 181
 182     loop .write_cell        ; } while (--cx)
 183
 184 ret
 185
 186 ; flip_vga_page() - flip active display page ----------------------------------
 187
 188 ; clobbers ax, dx
 189
 190 flip_vga_page:
 191
 192 call vsync_wait
 193
 194 xor word [currvgapg], VGAPGSZ   ; flip currvgapg
 195 setnz al                        ; al = !(currvgapg == 0)
 196
 197 mov ah, 0x05                ; select active display page
 198 int 0x10                    ; video services
 199
 200 ret
 201
 202 ; alive_neighbours() ----------------------------------------------------------
 203
 204 ; input:
 205 ; es:si     -> current grid
 206 ; cx        -> cell index
 207
 208 ; output:
 209 ; ax = # alive neighbours
 210
 211 ; clobbers ax, bx, dx
 212
 213 alive_neighbours:
 214 enter 5, 0
 215
 216 ; [bp - 1]: row
 217 ; [bp - 2]: col
 218 ; [bp - 3]: neighbours
 219 ; [bp - 4]: i
 220 ; [bp - 5]: j
 221
 222 mov ax, cx                  ; ax = idx
 223 mov bl, COLS                ; bl = COLS
 224 div bl                      ; al = idx / COLS ; ah = idx % COLS
 225
 226 mov [bp - 1], al            ; row = idx / COLS
 227 mov [bp - 2], ah            ; row = idx % COLS
 228 mov byte [bp - 3], 0        ; neighbours = 0
 229
 230 mov byte [bp - 4], -1       ; i = -1
 231 .i:                         ; do {
 232
 233     mov byte [bp - 5], -1           ; j = -1
 234 .j:                                 ; do {
 235
 236         mov al, [bp - 4]
 237         or al, [bp - 5]
 238         jz .continue                    ; if (!i && !j) continue
 239
 240         mov al, [bp - 1]
 241         add al, [bp - 4]                ; al = row + i
 242
 243         cmp al, 0
 244         jl .continue                    ; if (row + i < 0) continue
 245
 246         cmp al, ROWS
 247         jge .continue                   ; if (row + i >= ROWS) continue
 248
 249         mov ah, [bp - 2]
 250         add ah, [bp - 5]                ; ah = col + j
 251
 252         cmp ah, 0
 253         jl .continue                    ; if (col + j < 0) continue
 254
 255         cmp ah, COLS
 256         jge .continue                   ; if (col + j >= COLS) continue
 257
 258         movzx bx, ah                    ; bx = col + j
 259
 260         mov ah, COLS
 261         mul ah                          ; ax = (row + i) * COLS
 262
 263         add bx, ax                      ; bx = cell index
 264         shl bx, 1                       ; bx = grid offset
 265
 266         mov dx, [es:si + bx]            ; dl = cell state
 267
 268         cmp dl, ALIVE                   ; if (!ALIVE) continue
 269         jne .continue
 270
 271         inc byte [bp - 3]               ; neighbours++
 272
 273 .continue:
 274         inc byte [bp - 5]
 275         cmp byte [bp - 5], 1
 276         jle .j                      ; } while (++j <= 1)
 277
 278     inc byte [bp - 4]
 279     cmp byte [bp - 4], 1
 280     jle .i                  ; } while (++i <= 1)
 281
 282 movzx ax, byte [bp - 3]     ; ax = # alive neighbours
 283
 284 leave
 285 ret
 286
 287 ; write_next_cell_state() -----------------------------------------------------
 288
 289 ; input:
 290 ; es:si     -> current grid
 291 ; es:di     -> next grid
 292 ; cx        -> cell index
 293
 294 ; output:
 295 ; [es:di + cx * 2] = updated cell state
 296
 297 ; clobbers ax, bx, dx
 298
 299 write_next_cell_state:
 300
 301 call alive_neighbours       ; ax = # alive neighbours
 302
 303 mov bx, cx
 304 shl bx, 1
 305
 306 mov dx, [es:si + bx]        ; dl = cell current state
 307
 308 cmp dl, ALIVE               ; if (ALIVE) {
 309 jne .else
 310
 311 cmp ax, 2                   ;     if (n < 2)
 312 jl .dead                    ;         return DEAD
 313
 314 cmp ax, 3                   ;     if (n > 3)
 315 jg .dead                    ;         return DEAD
 316
 317 jmp .alive                  ;     return ALIVE
 318
 319 .else:                      ; }
 320
 321 cmp ax, 3                   ; if (n != 3)
 322 jne .dead                   ;     return DEAD
 323
 324 .alive:                     ; return ALIVE
 325 mov dl, ALIVE
 326 jmp .write
 327
 328 .dead:
 329 mov dl, DEAD
 330
 331 .write:
 332 mov [es:di + bx], dx
 333
 334 ret
 335
 336 ; write_next_vga_page() -------------------------------------------------------
 337
 338 ; clobbers di, si, ax, bx, cx, dx
 339
 340 write_next_vga_page:
 341
 342 mov si, [currvgapg]         ; es:si -> current page
 343
 344 mov di, VGAPGSZ
 345 xor di, si                  ; es:di -> next page
 346
 347 xor cx, cx                  ; i = 0
 348
 349 .update_loop:
 350 call write_next_cell_state
 351
 352 inc cx
 353 cmp cx, COLS * ROWS
 354 jl .update_loop             ; for i in [0 .. COLS * ROWS - 1]
 355
 356 ret
 357
 358 ; halt() - stop program execution ---------------------------------------------
 359
 360 halt:
 361
 362 cli                         ; disable interrupts
 363 hlt
 364 jmp halt
 365
 366 ; =============================================================================
 367
 368 times 510 - ($ - $$) db 0   ; fill remaining bytes with zeroes
 369 dw 0xaa55                   ; mbr magic byte